*=============Boost_Buck_Duty_Cycle_Plots==================


Sometimes being able to put more information on a single

plot is useful. Being able to sweep something can make it

harder for a problem to hide. 


=======================================================================


Boost_Buck_Converter

*

*  ___   / V1   D1        ___     R1 = 5K, 50, 10

* |VIN|_/  ________|/|___|OUT|__/\  /\  /\__

* |___| S1  |      |\|   |___|    \/  \/   _|_

*           |  _  _  _     |    C1         ///

*           | / \/ \/ \    |__||__

*           |_| () () |_      || _|_

*                L1    _|_       ///

*                      ///



boostBuckLoaded.jpg


 plot      out5k out50 out10 vs vd


=======================================================================


Sometimes being able to sweep in more than one direction

is useful. The plot above shows a Boost_Buck Converter

which has undergone a 0% to 100% sweep in duty cycle over

a 1msec transient analysis for three different output loads. 



===========Full_Netlist_For_Copy_Paste======================= 


Boost_Buck_Converter

*

*  ___   / V1   D1        ___     R1

* |VIN|_/  ________|/|___|OUT|__/\  /\  /\__

* |___| S1  |      |\|   |___|    \/  \/   _|_

*           |  _  _  _     |    C1         ///

*           | / \/ \/ \    |__||__

*           |_| () () |_      || _|_

*                L1    _|_       ///

*                      ///

VP        VP     0      DC     3.141592653589793

VT        VT     0      PWL    ( 0 0 1m .1m )

VD        VD     0      PWL    ( 0 0 1m  1 ) 

VIN       VIN    0      DC     5

B1        TRI    0      V =    acos( cos(v(VP)*v(VT)*2*1e6) )/v(VP) 

B2        VSW    0      V =    2*u( -v(TRI) +v(VD)) -1

B3        V1B    0      V =    5*u( v(VSW) ) 

*SXXXXXX  N+     N-     NC+    NC-    MODEL        <ON><OFF>


S1        VIN    V1     VSW    0      SWP

L1        V1     V1L    100u

RL1       V1L    0      1m 

D1        OUT5K  V1     DD

C1        OUT5K  0      3u

R1        OUT5K  0      5k


S2        VIN    V2     VSW    0      SWP

L2        V2     V2L    100u

RL2       V2L    0      1m 

D2        OUT50  V2     DD

C2        OUT50  0      3u

R2        OUT50  0      50


S3        VIN    V3     VSW    0      SWP

L3        V3     V3L    100u

RL3       V3L    0      1m 

D3        OUT10  V3     DD

C3        OUT10  0      3u

R3        OUT10  0      10


.MODEL    SWP    SW(    VT=2.6m VH=.2  RON=10u  ROFF=100MEG)

.model    DD     D(     IS=3.15e-18 ) 


*TRAN     TSTEP  TSTOP  TSTART TMAX        ?UIC?

.tran    .01u    1m    0      .01us   

*=========Run_Sim============================================ 

.control 

run 

set       pensize = 2 

plot      out5k out50 out10  vs   v(vd)

.endc 

.end